How to use the FIND function

What is the FIND function?

The FIND function returns the position of a specific string located in another string, reading left to right. Note, the FIND function is case-sensitive.

1. Introduction

What is the difference between the FIND function and the SEARCH function?

The FIND and SEARCH functions are nearly identical, with one key difference: FIND is case-sensitive while SEARCH is not. FIND only locates exact matches taking into account uppercase and lowercase letters. SEARCH will find a text string regardless of the case used in the search term or within the searched text.

For example, FIND would not match "battery" in "Battery", while SEARCH would find it even with a mismatch of cases. In all other aspects, FIND and SEARCH work the same - they search within a text string and return the starting position of a matched search term.

What is the difference between the FIND function and the FINDB function?

The FIND and FINDB functions handle character counting differently based on your default language setting in Excel. FINDB is designed for double-byte languages like Chinese, Japanese, Korean. It counts each double-byte character as 2 when a DBCS language is set as the default.

FIND always counts each character as 1, single-byte or double-byte, regardless of language setting. So FINDB will return larger position values than FIND for the same text in a DBCS language. The difference accounts for the double-byte characters taking 2 positions.

Japanese, Chinese (Simplified), Chinese (Traditional), and Korean are some examples of languages supporting DBCS.

What is DBCS?

It is an abbreviation of double-byte character set.

2. Syntax

FIND(find_text,within_text, [start_num])

find_text	Required. Is the text you want to find. ? and * wildcard characters are allowed.
within_text	Required. This argument is the text in which you want to search for.
[start_num]	Optional. The character number in within_text, counting from the left at which you want to start searching. If omitted 1 is used.

3. Example

The image above demonstrates the FIND function in cells D3 and D4. Cell D3 shows the FIND function searching for the text "friend" within the text string "Hello friend".

Formula in cell C3:

The formula returns 7 , "friend" is found at character number 7 in text string "Hello friend". FIND is case-sensitive, so it will only match the lowercase "friend".

Cell D4 demonstrates what happens if no match is found, FIND will return a #VALUE! error instead of a number. Test for errors using IFERROR() to provide user-friendly feedback. Here is an example of combining the FIND function and the IFERROR function:

Formula in cell D4:

The formula above shows "Not found!" in cell D4 if the specified search value in cell C4 is not found at all in cell B4.

Back to top

4. Function not working

If the text string is not found the FIND function returns a #VALUE! error. To avoid the error you have several options:

• The ISNUMBER function returns boolean values TRUE or FALSE, like this:
  =ISNUMBER(FIND(C3,B3))
• The IFERROR function to display a custom error message, demonstrated in section 3 above.
• The ISERROR function returns TRUE if the FIND function output is an error value and FALSE if not.

The #NAME error appears if you misspelled the FIND function.

4.1 Troubleshooting the error value

When you encounter an error value in a cell a warning symbol appears, displayed in the image above. Press with mouse on it to see a pop-up menu that lets you get more information about the error.

1. The first line describes the error if you press with left mouse button on it.
2. The second line opens a pane that explains the error in greater detail.
3. The third line takes you to the "Evaluate Formula" tool, a dialog box appears allowing you to examine the formula in greater detail.
4. This line lets you ignore the error value meaning the warning icon disappears, however, the error is still in the cell.
5. The fifth line lets you edit the formula in the Formula bar.
6. The sixth line opens the Excel settings so you can adjust the Error Checking Options.

Here are a few of the most common Excel errors you may encounter.

#NULL error - This error occurs most often if you by mistake use a space character in a formula where it shouldn't be. Excel interprets a space character as an intersection operator. If the ranges don't intersect an #NULL error is returned. The #NULL! error occurs when a formula attempts to calculate the intersection of two ranges that do not actually intersect. This can happen when the wrong range operator is used in the formula, or when the intersection operator (represented by a space character) is used between two ranges that do not overlap. To fix this error double check that the ranges referenced in the formula that use the intersection operator actually have cells in common.

#SPILL error - The #SPILL! error occurs only in version Excel 365 and is caused by a dynamic array being to large, meaning there are cells below and/or to the right that are not empty. This prevents the dynamic array formula expanding into new empty cells.

#DIV/0 error - This error happens if you try to divide a number by 0 (zero) or a value that equates to zero which is not possible mathematically.

#VALUE error - The #VALUE error occurs when a formula has a value that is of the wrong data type. Such as text where a number is expected or when dates are evaluated as text.

#REF error - The #REF error happens when a cell reference is invalid. This can happen if a cell is deleted that is referenced by a formula.

#NAME error - The #NAME error happens if you misspelled a function or a named range.

#NUM error - The #NUM error shows up when you try to use invalid numeric values in formulas, like square root of a negative number.

#N/A error - The #N/A error happens when a value is not available for a formula or found in a given cell range, for example in the VLOOKUP or MATCH functions.

#GETTING_DATA error - The #GETTING_DATA error shows while external sources are loading, this can indicate a delay in fetching the data or that the external source is unavailable right now.

4.2 The formula returns an unexpected value

To understand why a formula returns an unexpected value we need to examine the calculations steps in detail. Luckily, Excel has a tool that is really handy in these situations. Here is how to troubleshoot a formula:

1. Select the cell containing the formula you want to examine in detail.
2. Go to tab “Formulas” on the ribbon.
3. Press with left mouse button on "Evaluate Formula" button. A dialog box appears.
   The formula appears in a white field inside the dialog box. Underlined expressions are calculations being processed in the next step. The italicized expression is the most recent result. The buttons at the bottom of the dialog box allows you to evaluate the formula in smaller calculations which you control.
4. Press with left mouse button on the "Evaluate" button located at the bottom of the dialog box to process the underlined expression.
5. Repeat pressing the "Evaluate" button until you have seen all calculations step by step. This allows you to examine the formula in greater detail and hopefully find the culprit.
6. Press "Close" button to dismiss the dialog box.

There is also another way to debug formulas using the function key F9. F9 is especially useful if you have a feeling that a specific part of the formula is the issue, this makes it faster than the "Evaluate Formula" tool since you don't need to go through all calculations to find the issue..

1. Enter Edit mode: Double-press with left mouse button on the cell or press F2 to enter Edit mode for the formula.
2. Select part of the formula: Highlight the specific part of the formula you want to evaluate. You can select and evaluate any part of the formula that could work as a standalone formula.
3. Press F9: This will calculate and display the result of just that selected portion.
4. Evaluate step-by-step: You can select and evaluate different parts of the formula to see intermediate results.
5. Check for errors: This allows you to pinpoint which part of a complex formula may be causing an error.

The image above shows cell reference C4 converted to hard-coded value using the F9 key. The FIND function requires that the specified find_text argument exists in the within_text argument which is not the case in this example. We have found what is wrong with the formula.

Tips!

• View actual values: Selecting a cell reference and pressing F9 will show the actual values in those cells.
• Exit safely: Press Esc to exit Edit mode without changing the formula. Don't press Enter, as that would replace the formula part with the calculated value.
• Full recalculation: Pressing F9 outside of Edit mode will recalculate all formulas in the workbook.

Remember to be careful not to accidentally overwrite parts of your formula when using F9. Always exit with Esc rather than Enter to preserve the original formula. However, if you make a mistake overwriting the formula it is not the end of the world. You can “undo” the action by pressing keyboard shortcut keys CTRL + z or pressing the “Undo” button

4.3 Other errors

Floating-point arithmetic may give inaccurate results in Excel - Article

Floating-point errors are usually very small, often beyond the 15th decimal place, and in most cases don't affect calculations significantly.

Back to top

Back to top

5. Return all positions of a given substring

The FIND function returns the position of a specific string located in another string, reading left to right. Note, the position of the first instance is returned, the others are not displayed.

This example demonstrates a formula that extracts all positions of all instances of a specific substring in another string also considering upper and lower letters. FIND function is not even used in this formula.

Formula in cell E3:

Cell E3 displays 2 and 10 which are the positions of "e" in "Hello friendly Elf" reading from left to right. The formula works fine with larger substrings as well.

Explaining formula

Step 1 - Count characters

The LEN function returns the number of characters in a cell value.

Function syntax: LEN(text)

LEN(B3)

becomes

LEN("Hello friendly Elf")

and returns 18.

Step 2 -  Create a sequence from 1 to n

The SEQUENCE function creates a list of sequential numbers.

Function syntax: SEQUENCE(rows, [columns], [start], [step])

SEQUENCE(,LEN(B3))

becomes

SEQUENCE(,18)

and returns

{1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18}

Step 3 -  Split string based on character count of substring

The MID function returns a substring from a string based on the starting position and the number of characters you want to extract.

Function syntax: MID(text, start_num, num_chars)

MID(B3,SEQUENCE(,LEN(B3)),LEN(C3))

becomes

MID("Hello friendly Elf",{1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18},1)

and returns

{"H","e","l","l","o"," ","f","r","i","e","n","d","l","y"," ","E","l","f"}

Step 4 - Compare array to substring

The EXACT function checks if two values are precisely the same, it returns TRUE or FALSE. The EXACT function also considers upper case and lower case letters.

Function syntax: EXACT(text1, text2)

EXACT(MID(B3,SEQUENCE(,LEN(B3)),LEN(C3)),C3)

becomes

EXACT({"H","e","l","l","o"," ","f","r","i","e","n","d","l","y"," ","E","l","f"},"e")

and returns

{FALSE,TRUE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,TRUE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE}

Step 5 -  Filter sequence based on boolean values

The FILTER function extracts values/rows based on a condition or criteria.

Function syntax: FILTER(array, include, [if_empty])

FILTER(SEQUENCE(,LEN(B3)),MID(B3,SEQUENCE(,LEN(B3)),LEN(C3))=C3)

becomes

FILTER({1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18},{FALSE,TRUE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,TRUE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE,FALSE})

and returns

{2,10}

Step 6 -  Join strings

The TEXTJOIN function combines text strings from multiple cell ranges.

Function syntax: TEXTJOIN(delimiter, ignore_empty, text1, [text2], ...)

TEXTJOIN(",",1,FILTER(SEQUENCE(,LEN(B3)),MID(B3,SEQUENCE(,LEN(B3)),LEN(C3))=C3))

becomes

TEXTJOIN(",",1,{2,10})

and returns

"2,10".

Step 7 -  Simplify formula

The LET function lets you name intermediate calculation results which can shorten formulas considerably and improve performance.

Function syntax: LET(name1, name_value1, calculation_or_name2, [name_value2, calculation_or_name3...])

=TEXTJOIN(",",1,FILTER(SEQUENCE(,LEN(B3)),EXACT(MID(B3,SEQUENCE(,LEN(B3)),LEN(C3)),C3)))

z - SEQUENCE(,LEN(B3))

=LET(z,SEQUENCE(,LEN(B3)),TEXTJOIN(",",1,FILTER(z,EXACT(MID(B3,z,LEN(C3)),C3))))

Useful resources

FIND function - Microsoft Support
Excel FIND and SEARCH functions with formula examples

'FIND' function examples

Functions in 'Text' category

The FIND function function is one of 29 functions in the 'Text' category.

Excel function categories

Excel categories

Leave a Comment